关于ASP上传图片水印的问题
发布网友
发布时间：2022-04-19 23:42
共3个回答
热心网友
时间：2022-04-20 01:11
注册组件的方法:
命令提示符下输入"regsvr32 [Dll路径]" 就可以了．
图片添加水印无非就是获得图片大小,然后把水印写上去..ASP代码只是起个控制组件的作用.用代码来说明一切吧.
一:获得图片大小(这里是用象素值表示的.学PhotoShop的朋友都应该明白)
<%
set obj=server.CreateObject("wsImage.Resize") ''调用组件
obj.LoadSoucePic server.mappath("25.jpg") ''打开图片,图片名字是25.jpg
obj.GetSourceInfo iWidth,iHeight
response.write "图片宽度:" & iWidth & "<br>" ''获得图片宽度
response.write "图片高度:" & iHeight & "<br>" ''获得图片高度
strError=obj.errorinfo
if strError<>"" then
response.write obj.errorinfo
end if
obj.free
set obj=nothing
%>
''----------------------------------------------------------------''
二:添加文字水印
<%
set obj=server.CreateObject("wsImage.Resize")
obj.LoadSoucePic server.mappath("25.jpg") ''装载图片
obj.Quality=75
obj.TxtMarkFont = "华文彩云" ''设置水印文字字体
obj.TxtMarkBond = false ''设置水印文字的粗细
obj.MarkRotate = 0 ''水印文字的旋转角度
obj.TxtMarkHeight = 25 ''水印文字的高度
obj.AddTxtMark server.mappath("txtMark.jpg"), "带你离境", &H00FF00&, 10, 70
strError=obj.errorinfo ''生成图片名字,文字颜色即水印在图片的位置
if strError<>"" then
response.write obj.errorinfo
end if
obj.free
set obj=nothing
%>
''----------------------------------------------------------------''
三:添加图片水印
<%
set obj=server.CreateObject("wsImage.Resize")
obj.LoadSoucePic server.mappath("25.jpg") ''装载图片
obj.LoadImgMarkPic server.mappath("blend.bmp") ''装载水印图片
obj.Quality=75
obj.AddImgMark server.mappath("imgMark.jpg"), 315, 220,&hFFFFFF, 70
strError=obj.errorinfo ''生成图片名字,文字颜色即水印在图片的位置
if strError<>"" then
response.write obj.errorinfo
end if
obj.free
set obj=nothing
%>
''----------------------------------------------------------------''
其实给图片添加水印就这么简单.然后我在说下WsImage.dll组件的另外两个主要用法.包括:
剪裁图片,生成图片的缩略图.
还是以我得习惯,用代码加注释说明:
剪裁图片:
<%
set obj=server.CreateObject("wsImage.Resize")
obj.LoadSoucePic server.mappath("25.jpg")
obj.Quality=75
obj.cropImage server.mappath("25_crop.jpg"),100,10,200,200 ''定义裁减大小和生成图片名字
strError=obj.errorinfo
if strError<>"" then
response.write obj.errorinfo
end if
obj.free
set obj=nothing
%>
详细注释:裁减图片用到了WsImage的CropImage方法.其中定义生成图片时候,100,10是左上角的裁减点,即离图片左边是100象素,顶端10象素.后两个200代表的是裁减的宽带和高和高度.
''----------------------------------------------------------------''
生成图片缩略图:
<%
set obj=server.CreateObject("wsImage.Resize")
obj.LoadSoucePic server.mappath("25.jpg") ''加载图片
obj.Quality=75
obj.OutputSpic server.mappath("25_s.jpg"),0.5,0.5,3 ''定义缩略图的名字即大小
strError=obj.errorinfo
if strError<>"" then
response.write obj.errorinfo
end if
obj.free
set obj=nothing
%>
详细说明:
产生缩略图共有四种导出方式：
(1) obj.OutputSpic server.mappath("25_s.jpg"),200,150,0
200为输出宽，150为输出高，这种输出形式为强制输出宽高，可能引起图片变形。
(2) obj.OutputSpic server.mappath("25_s.jpg"),200,0,1
以200为输出宽，输出高将随比列缩放。
(3) obj.OutputSpic server.mappath("25_s.jpg"),0,200,2
以200为输出高，输出宽将随比列缩放。
(4) obj.OutputSpic server.mappath("25_s.jpg"),0.5,0.5,3
第一个0.5表示生成的缩略图是原图宽的一半，即表示宽缩小比例。
第二个0.5表示生成的缩略图是原图高的一半，即表示高缩小比例。
宽高的缩小比例一致意味着将对原图进行比例缩小。宽高的缩放比例如果大于1，则对原图进行放大。
aspjpeg组件下载
http://www.haicode.net/soft/book/aspzj/down-70.html
热心网友
时间：2022-04-20 02:29
增加水印使用的是一个名叫ASPJPEG的ASP组件，版本是1.5版本，使用这个图象处理组件，可以轻松地做出图片的缩略图和为图片加上水印功能。下面简单介绍一下使用方法：
先要到Oblog的下载页面上，在“OBLOG相关组件下载”处，下载AspJpeg v1.5.0.0，然后执行下载得到的文件，安装该组件。
然后在ASP代码里增加一点点代码即可，增加的位置可以放在上传图片完成后，取得图片地址，进行修改。对于Z-Blog的使用者，直接将下面代码复制到c_system_lib.asp文件的TUpLoadFile类中的Upload函数的结尾即可实现水印功能。
1、为图片加入水印功能
Dim Jpeg
Set Jpeg = Server.CreateObject("Persits.Jpeg") ' 建立对象
Jpeg.Open BlogPath & "/upload/" & FileName ' 图片所在位置
Jpeg.Canvas.Font.Color = &H000000 ' 颜色,这里是设置成:黑
Jpeg.Canvas.Font.Family = "方正隶变简体" ' 设置字体
Jpeg.Canvas.Font.Bold = False '是否设置成粗体
Jpeg.Canvas.Font.Size = 26 '字体大小
Jpeg.Canvas.Font.Quality = 4 ' 文字清晰度
Jpeg.Canvas.Print Jpeg.OriginalWidth/2-170,Jpeg.OriginalHeight-30, "www.WILLIAMLONG.INFO" '水印文字
Jpeg.Save BlogPath & "/upload/" & FileName ' 保存文件
Set Jpeg = Nothing
2、为图片制作缩略图
Dim Jpeg
Set Jpeg = Server.CreateObject("Persits.Jpeg") ' 建立对象
Jpeg.Open BlogPath & "/upload/" & FileName ' 图片所在位置
Jpeg.Width = Jpeg.OriginalWidth / 2
Jpeg.Height = Jpeg.OriginalHeight / 2
' 设置缩略图大小（这里比例设定为50%），也可以给他准确的数值，比如Jpeg.Width=120
Jpeg.Save BlogPath & "/upload/" & FileName ' 保存文件
Set Jpeg = Nothing
本文来源于月光博客 http://www.williamlong.info , 原文地址：http://www.williamlong.info/archives/539.html
热心网友
时间：2022-04-20 04:04
打浪个多勒字,
没累蓝,?
这些看都看不懂,
不是看懂看不懂的问题,
是看见黑压压的一片就不想继续看下去的问题,
